Third CTL strategy example. Fast Stochastics 1min + 5min + time entry with SMS alert + emergency stop.

This code had some serious errors found by a reader. This code has been corrected on 27/05/2011. The error was in the lines

if t>=t1 and t<=t2 and stoch5min[currentbar] < 24 and stoch5min[currentbar] < 17
if t>=t1 and t<=t2 and stoch1min[currentbar] < 24 and stoch5min[currentbar] < 17

if t>=t1 and t<=t2 and stoch5min[currentbar] > 76 and stoch5min[currentbar] > 83
if t>=t1 and t<=t2 and stoch1min[currentbar] > 76 and stoch5min[currentbar] > 83

not long() and not long() then
not long() and not short() then

This greatly improves the performance of the strategy.

Many thanks to the anonymous reader for pointing out the error.

First the code:

************************************************************************

strategy min1min5stochastics;


/* written by ctlprogrammer for EUR/USD timeframe 1min*/
/*Warning for demonstration purpose only, no live trading please*/
/* http://ctltrading.blogspot.com*/


input h1=6,h2=23,MaxLoss=50;
/*Warning MaxLoss must be optimized in backtest first*/


vars currentbar = 1, lots = 1,stoch1min(series),stoch5min(series),t=0,t1=0,t2=0;
begin
  currentbar := back(close);
  if currentbar < 40 then return;
 
  Fast_Stochastics(close,5,3);
  stoch1min:=Fast_Stochastics.line_d;
 
  Fast_Stochastics(close,25,15);
  stoch5min:=Fast_Stochastics.line_d;
 
  t:=hour(timestamp[currentbar])*60;
  t1:=h1*60;
  t2:=h2*60;
 
 
  if t>=t1 and t<=t2 and stoch1min[currentbar] < 24 and stoch5min[currentbar] < 17 and
  not short() and not long() then
  begin
  buy(lots);
  alert("sms","long");
  end;
  if t>=t1 and t<=t2 and stoch1min[currentbar] > 76 and stoch5min[currentbar] > 83 and
  not short() and not long() then
  begin
  sell(lots);
  alert("sms","short");
  end;


  if stoch1min[currentbar]>82 and long() then exitlong();
  if stoch1min[currentbar]<18 and short() then exitshort();
 
  if fpl()<-MaxLoss then
  begin
  if long() then exitlong();
  if short() then exitshort();
  end;
 
  end.

************************************************************************

This strategy goes long between h1 en h2 when

Fast_Stochastics(close,5,3).line_d is lower than 24 and

Fast_Stochastics(close,25,15).line_d lower then 17

This strategy goes short between h1 en h2 when

Fast_Stochastics(close,5,3).line_d is higher than 76 and

Fast_Stochastics(close,25,15).line_d higher then 83

In both case trader is warned with SMS signal.

Long position is closed when Fast_Stochastics(close,5,3).line_d > 82

Short position is closed when Fast_Stochastics(close,5,3).line_d < 18

For protection startegy has a maximum loss protection. This should be optimized before using the strategy.

Too small ==> many small losses and few wins

Too big ==> many wins but big loosers